@Echo Off
Rem ---------------------------------------------------------------------------
Rem JOnAS: Java(TM) Open Application Server
Rem Copyright (C) 1999-2005 Bull S.A.
Rem Contact: jonas-team@objectweb.org
Rem
Rem This library is free software; you can redistribute it and/or
Rem modify it under the terms of the GNU Lesser General Public
Rem License as published by the Free Software Foundation; either
Rem version 2.1 of the License, or any later version.
Rem
Rem This library is distributed in the hope that it will be useful,
Rem but WITHOUT ANY WARRANTY; without even the implied warranty of
Rem MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
Rem Lesser General Public License for more details.
Rem
Rem You should have received a copy of the GNU Lesser General Public
Rem License along with this library; if not, write to the Free Software
Rem Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307
Rem USA
Rem
Rem ---------------------------------------------------------------------------
Rem $Id$
Rem ---------------------------------------------------------------------------

Rem Keep variables local to this script
setlocal
set ARGS=

Rem check JONAS_ROOT and JONAS_BASE
if [%JONAS_ROOT%]==[] goto setroot
Rem Required for carol.properties file (add JONAS_BASE\conf to classpath)
call %JONAS_ROOT%\bin\nt\setenv.bat
set JONAS_LIB=%JONAS_ROOT%\lib

Rem check client.jar
if not exist %JONAS_LIB%\client.jar goto noclt

Rem ---------------------------------------------
Rem Get args
Rem ---------------------------------------------
:loop_on_args
Set VALUE=%~1
if %1==-cp     goto cp_arg
if %1==-security goto security
if %VALUE:~0,2%==-D goto java_opts
set ARGS=%ARGS% %1
goto next_arg

Rem Use security manager for jclient ?
:security
Set JAVA_OPTS=%JAVA_OPTS% -Djava.security.manager -Djava.security.policy=%JONAS_BASE%\conf\java.policy
goto next_arg

Rem Add -D System Properties
:java_opts
Set PROP=%~1
shift
Set PROP=%PROP%=%1
Set JAVA_OPTS=%JAVA_OPTS% %PROP%
goto next_arg

:cp_arg
shift
Set CLASSPATH=%CLASSPATH%;%~1
goto next_arg

:next_arg
shift
if not [%1]==[] goto loop_on_args

Set CLASSPATH=%CLASSPATH%;%JONAS_LIB%\client.jar
goto :opt_orb

:opt_orb
Rem ---------------------------------------------
Rem Set options for ORB
Rem ---------------------------------------------
set JAVA_OPTS=%JAVA_OPTS% -Djava.security.auth.login.config=%JONAS_BASE%\conf\jaas.config
set JAVA_OPTS=%JAVA_OPTS% -Djava.endorsed.dirs=%JONAS_ROOT%\lib\endorsed
%JAVA% %JAVA_OPTS% org.objectweb.jonas.client.ClientContainer %ARGS%
goto :EOF

:noclt
echo client.jar file must be present in JONAS_ROOT\lib directory
goto :EOF


:setroot
echo JONAS_ROOT not set.
goto :EOF
